易语言取指针源码

易语言取指针源码

.版本 2
.支持库 spec

.程序集 程序集

.子程序 _启动子程序, 整数型
.局部变量 a, 整数型
.局部变量 b, 文本型
.局部变量 c, 字节集
.局部变量 d, 字节型
.局部变量 e, WSABUF
.局部变量 aa, 整数型, , "2"
.局部变量 bb, 文本型, , "2"
.局部变量 cc, 字节集, , "2"
.局部变量 dd, 字节型, , "2"
.局部变量 ee, WSABUF, , "2"

a ＝ 11
b ＝ “11”
c ＝ 到字节集 (“111”)
d ＝ 到字节 (11)
e.len ＝ 11
e.buf ＝ 到字节集 (“111”)
调试输出 (“整数  ”, 取变量地址 (a), 取变量数据地址 (a), , 取指针 (a), 取指针 (a, 真, 真))
调试输出 (“文本  ”, 取变量地址 (b), 取变量数据地址 (b), , 取指针 (b), 取指针 (b, 真))
调试输出 (“字节集”, 取变量地址 (c), 取变量数据地址 (c), , 取指针 (c), 取指针 (c, 真, , 真))
调试输出 (“字节  ”, 取变量地址 (d), 取变量数据地址 (d), , 取指针 (d), 取指针 (d, 真, 真))
调试输出 (“自定义”, 取变量地址 (e), 取变量数据地址 (e), , 取指针 (e), 取指针 (e, 真, 真))

输出调试文本 (“间隔”)
aa [1] ＝ 1
aa [2] ＝ 2
bb [1] ＝ “1”
bb [2] ＝ “2”
cc [1] ＝ 到字节集 (“111”)
cc [2] ＝ 到字节集 (“222”)
dd [1] ＝ 到字节 (11)
dd [2] ＝ 到字节 (22)
ee [1].len ＝ 11
ee [1].buf ＝ 到字节集 (“111”)
ee [2].len ＝ 22
ee [2].buf ＝ 到字节集 (“222”)
调试输出 (“整数  ”, 取变量地址 (aa), 取变量数据地址 (aa), , 取数组指针 (aa), 取数组指针 (aa, 真))
调试输出 (“文本  ”, 取变量地址 (bb), 取变量数据地址 (bb), , 取数组指针 (bb), 取数组指针 (bb, 真))
调试输出 (“字节集”, 取变量地址 (cc), 取变量数据地址 (cc), , 取数组指针 (cc), 取数组指针 (cc, 真))
调试输出 (“字节  ”, 取变量地址 (dd), 取变量数据地址 (dd), , 取数组指针 (dd), 取数组指针 (dd, 真))
调试输出 (“自定义”, 取变量地址 (ee), 取变量数据地址 (ee), , 取数组指针 (ee), 取数组指针 (ee, 真))
返回 (0)

.子程序 取指针, 整数型, , 取变量地址
.参数 数据变量, 通用型, 参考
.参数 取数据地址, 逻辑型, 可空, 假=变量地址 真=数据地址
.参数 数值或自定义, 逻辑型, 可空
.参数 字节集类型, 逻辑型, 可空

.判断开始 (取数据地址 且 数值或自定义 ＝ 假)
    置入代码 ({ 139, 69, 8, 139, 0 })
.默认
    置入代码 ({ 139, 69, 8 })
.判断结束
.如果真 (字节集类型)
    置入代码 ({ 129, 192, 8, 0, 0, 0 })
.如果真结束
置入代码 ({ 201, 195 })
返回 (0)

.子程序 取数组指针, 整数型, , 取数组变量地址
.参数 数组变量, 通用型, 参考 数组
.参数 取数据地址, 逻辑型, 可空, 假=变量地址 真=数据地址

.判断开始 (取数据地址)
    置入代码 ({ 139, 69, 8, 139, 0, 133, 192, 116, 7, 131, 192, 8, 201, 194, 4, 0 })
.默认
    置入代码 ({ 139, 69, 8, 201, 194, 4, 0 })
.判断结束
返回 (0)

@woxl