易语言纯源码毫秒级调用WIA对象方式对大图片缩放,适用于取略缩图

实测 15M图片  宽3000像素 高5000像素 缩放时间在300毫秒左右

支持指定宽高缩放、支持比例缩放、只支持常见图片格式

支持直接返回字节集、或者直接写出指定目录。

目前发现的缺点也可以算优点  就是 缩小后 图片是真的缩小    而不是缩小后 像素还在 重新放大将不会还原图片

@伊银

.版本 2
.支持库 spec

.程序集 窗口程序集1

.子程序 _按钮1_被单击
.局部变量 tim, 整数型

tim ＝ 取启动时间 ()
图片框1.图片 ＝ WIA图片缩放 (编辑框1.内容, 100, 100, 真)
调试输出 (取启动时间 () － tim)

.子程序 WIA图片缩放, 字节集, , 返回修改大小的图片字节集
.参数 文件名, 文本型
.参数 设置宽度, 整数型
.参数 设置高度, 整数型
.参数 按比例缩放, 逻辑型, 可空, 默认假
.参数 输出路径, 文本型, 可空, 保存修改大小的图片文件
.局部变量 img, 对象
.局部变量 ip, 对象

img.创建 (“WIA.ImageFile”, )
ip.创建 (“WIA.ImageProcess”, )
img.方法 (“LoadFile”, 文件名)
ip.读对象型属性 (“Filters”, ).方法 (“Add”, ip.读对象型属性 (“FilterInfos”, ).读对象型属性 (“Item”, “Scale”).读文本属性 (“FilterID”, ), 0)
ip.读对象型属性 (“Filters”, ).读对象型属性 (“Item”, 1).读对象型属性 (“Properties”, ).读对象型属性 (“Item”, “MaximumHeight”).写属性 (“Value”, 设置高度)
ip.读对象型属性 (“Filters”, ).读对象型属性 (“Item”, 1).读对象型属性 (“Properties”, ).读对象型属性 (“Item”, “MaximumWidth”).写属性 (“Value”, 设置宽度)
ip.读对象型属性 (“Filters”, ).读对象型属性 (“Item”, 1).读对象型属性 (“Properties”, ).读对象型属性 (“Item”, “PreserveAspectRatio”).写属性 (“Value”, 按比例缩放)
img ＝ ip.对象型方法 (“Apply”, img)
.如果真 (是否为空 (输出路径) ＝ 假)
    img.方法 (“SaveFile”, 输出路径)
.如果真结束
返回 (img.读对象型属性 (“FileData”, ).读属性 (“BinaryData”, ).取字节集 ())