zsms免费短信接收平台模块源码

zsms免费短xin接收平台模块源码，号码数量不多，但免费

部分代码：

.版本 2

.程序集 ZSms, , 公开

.子程序 _初始化, , , 当基于本类的对象被创建后，此方法会被自动调用



.子程序 _销毁, , , 当基于本类的对象被销毁前，此方法会被自动调用



.子程序 getPhone, 逻辑型, 公开
.参数 area, 文本型, 可空, 指定区号，如86
.参数 num, 整数型, 可空, 获取数量
.参数 phones, Phone, 参考 可空 数组
.参数 errorMsg, 文本型, 参考 可空
.局部变量 str, 文本型
.局部变量 正则, 正则表达式类
.局部变量 i, 整数型
.局部变量 _phone, Phone

str ＝ 编码_URL解码 (到文本 (网页_访问 (“http://www.z-sms.com/”)), 真)
.如果真 (str ＝ “”)
    errorMsg ＝ “连接超时”
    返回 (假)
.如果真结束
重定义数组 (phones, 假, 0)
正则.创建 (#正则_getPhone, str)
.计次循环首 (正则.取匹配数量 (), i)
    .如果真 (取数组成员数 (phones) ≥ num 且 num ≠ 0)
        跳出循环 ()
    .如果真结束
    .如果真 (area ＝ “” 或 area ＝ 正则.取子匹配文本 (i, 1))
        _phone.area ＝ 正则.取子匹配文本 (i, 1)
        _phone.phone ＝ 正则.取子匹配文本 (i, 2)
        加入成员 (phones, _phone)
    .如果真结束

.计次循环尾 ()
.如果 (取数组成员数 (phones) ＞ 0)
    返回 (真)
.否则
    errorMsg ＝ “无号码可取”
    返回 (假)
.如果结束


.子程序 getMessage, 逻辑型, 公开
.参数 phone, 文本型
.参数 messages, Message, 参考 可空 数组
.参数 errorMsg, 文本型, 参考 可空
.局部变量 str, 文本型
.局部变量 正则, 正则表达式类
.局部变量 i, 整数型
.局部变量 _message, Message

str ＝ 编码_URL解码 (到文本 (网页_访问 (“http://www.z-sms.com/lv?pho_num=” ＋ phone ＋ “&1”)), 真)
.如果真 (str ＝ “”)
    errorMsg ＝ “连接超时”
    返回 (假)
.如果真结束
重定义数组 (messages, 假, 0)
正则.创建 (#正则_getMessage, str)
.计次循环首 (正则.取匹配数量 (), i)
    _message.receiveTime ＝ 删全部空 (正则.取子匹配文本 (i, 1))
    _message.from ＝ 删全部空 (正则.取子匹配文本 (i, 2))
    _message.msg ＝ 删全部空 (正则.取子匹配文本 (i, 3))
    加入成员 (messages, _message)
.计次循环尾 ()
.如果 (取数组成员数 (messages) ＞ 0)
    返回 (真)
.否则
    errorMsg ＝ “无短信可取”
    返回 (假)
.如果结束

@Skwen